Batch - Get Symantec Definition
Environment
2009-OCT-21
Code
- Microsoft Windows Server 2003
- Symantec AntiVirus 10.1.X.X
2009-OCT-21
Code
rem =================================
rem Version 2009OCT21
rem Basic requirement
rem =================================
@set DEFWHERE=C:\bin\SAVDef
@set FTPSERVER=Server
@set SAVROOT=C:\Program Files\Symantec AntiVirus
@set SAVLOGON=%SAVROOT%\Logon
rem =================================
rem FTP Connecttion Setting
rem
rem Assuming the conn.conf on the same folder of this script
rem =================================
echo open %FTPSERVER%> conn.conf
echo anonymous>> conn.conf
echo email@address.com>> conn.conf
echo cd SAVUpdate>> conn.conf
echo lcd %DEFWHERE%>> conn.conf
echo bin>> conn.conf
echo hash>> conn.conf
echo get navup8.exe >> conn.conf
echo bye>> conn.conf
rem =================================
rem FTP Dowloand the definitions
rem =================================
ftp -s:conn.conf
rem =================================
rem Unzip the received definitions
rem
rem The definition is unzipped on the current folder
rem =================================
call "%DEFWHERE%\navup8.exe"
rem =================================
rem Copy the received definitions the root and logon folders of SAV
rem =================================
copy /y "%DEFWHERE%\*.xdb" "%SAVROOT%"
copy /y "%DEFWHERE%\*.xdb" "%SAVLOGON%"
rem =================================
rem Final
rem =================================
del "%DEFWHERE%\conn.conf"
del "%DEFWHERE%\navup8.exe"
del "%DEFWHERE%\*.xdb"
set DEFWHERE=
set FTPSERVER=
set SAVROOT=
set SAVLOGON=